[ptxdist] [PATCH v2 2/2] configure.ac: add check for GNU coreutils

["Andreas Bießmann" <andreas@biessmann.de>]

Some scripts require GNU coreutils (especially the -- argument split is
problematical on BSD systems). This patch adds a macro to detect GNU coreutils
version of these tools and utilizes the macro to check for the most important
tools which break the build on Mac OS X.

Signed-off-by: Andreas Bießmann <andreas@biessmann.de>
---
changes since v1:
 * add m4 macro to check for GNU coreutils
 * squash all previous checks into one patch

 Makefile.in  |    4 ++++
 configure.ac |   14 ++++++++++++++
 2 files changed, 18 insertions(+), 0 deletions(-)

diff --git a/Makefile.in b/Makefile.in
index 62fabf6..ff55638 100644
--- a/Makefile.in
+++ b/Makefile.in
@@ -78,6 +78,10 @@ install-environment: all dirty-check
 	@mkdir -p "$(DESTDIR)$(instdir)"
 	@mkdir -p $(DESTDIR)$(instdir)/bin
 	@ln -sf @SED@ $(DESTDIR)$(instdir)/bin/sed
+	@ln -sf @GNU_chmod@ $(DESTDIR)$(instdir)/bin/chmod
+	@ln -sf @GNU_mv@ $(DESTDIR)$(instdir)/bin/mv
+	@ln -sf @GNU_rm@ $(DESTDIR)$(instdir)/bin/rm
+	@ln -sf @GNU_md5sum@ $(DESTDIR)$(instdir)/bin/md5sum
 
 dist: dirty-check
 	@rm -rf "$(project)"
diff --git a/configure.ac b/configure.ac
index 7a34e7a..3044188 100644
--- a/configure.ac
+++ b/configure.ac
@@ -133,6 +133,20 @@ case "$SED_VERSION" in
 esac
 AC_MSG_RESULT([$SED_VERSION])
 
+dnl check for gnu coreutils
+AC_DEFUN([GNU_COREUTILS],
+	[AC_CACHE_CHECK([for $1 from GNU coreutils], [ac_cv_path_gnu_$1],
+		[AC_PATH_PROGS_FEATURE_CHECK([gnu_$1], [g$1 $1.gnu $1],
+			[[out=`$ac_path_gnu_$1 --version 2>/dev/null | $SED -ne "s/.*\(GNU\) coreutils.*/\1/p"`
+				test "x$out" = xGNU && ac_cv_path_gnu_$1=$ac_path_gnu_$1 ac_path_gnu_$1_found=:]],
+			[AC_MSG_ERROR([could not find $1 from GNU coreutils])])])
+	AC_SUBST([GNU_$1], [$ac_cv_path_gnu_$1])])
+
+GNU_COREUTILS(chmod)
+GNU_COREUTILS(mv)
+GNU_COREUTILS(rm)
+GNU_COREUTILS(md5sum)
+
 dnl Check for egrep
 AC_PROG_EGREP
 
-- 
1.7.7.4


-- 
ptxdist mailing list
ptxdist@pengutronix.de